OpenOffice.org Forum :: How to access or change the user's profile

[Home] [FAQ] [Search] [Memberlist] [Usergroups] [Register]

[Profile] [Log in to check your private messages] [Log in]

How to access or change the user's profile

OOoForum.org Forum Index -> OpenOffice.org Code Snippets

View previous topic :: View next topic

Author

Message

DannyB
Moderator

Joined: 02 Apr 2003
Posts: 4021
Location: Lawrence, Kansas, USA

Posted: Wed Jun 15, 2005 7:36 am Post subject: How to access or change the user's profile

Here is an example of how to play mind games with the user's profile.

This code started from this conversation.
http://www.oooforum.org/forum/viewtopic.phtml?p=82006#82006

Code:

Sub Main
ShowUserProfile()
'ChangeUserProfile()
End Sub

Sub ShowUserProfile()
oConfigData_UserProfile = GetConfigAccess( "/org.openoffice.UserProfile/Data", False )

cCR = Chr(13)
MsgBox "Country: " + oConfigData_UserProfile.c _
   + cCR + "Company: " + oConfigData_UserProfile.o _
   + cCR + "Name: " + oConfigData_UserProfile.givenname _
   + cCR + "Initials: " + oConfigData_UserProfile.initials

' Here is a list of properties found in the schema at...
' /opt/OpenOffice.org1.9.104/share/registry/schema/org/openoffice/UserProfile.xcs
' or for some systems...
' C:\Program Files\OpenOffice.org 1.9.104\share\registry\schema\org\openoffice\UserProfile.xcs
'
' o       Specifies the name of the user's company.
' givenname Specifies the first name of the user.
' sn       Specifies the last name of the user.
' initials Specifies the user's initials.
' street    Specifies the street where the use lives.
' l       Specifies the city where the user lives.
' st       Specifies the state where the user lives.
' postalcode Specifies the user's ZIP-code.
' c       Specifies the country where the user lives.
' title    Specifies the user's title.
' position Specifies the users position. This field is only present for backward compatibility. It is not defined for ldap orgPerson.
' homephone Specifies the user's private telephone number.
' telephonenumber Specifies the user's telephone number at work.
' facsimiletelephonenumber Specifies the user's fax number.
' mail    Specifies the user's e-mail address.
' UserGroup This field is kept for backwards compatibility.
End Sub

Sub ChangeUserProfile()
oConfigData_UserProfile = GetConfigAccess( "/org.openoffice.UserProfile/Data", True, True, False )

' Change the user's country.
'oConfigData_UserProfile.c = "United States of America"
oConfigData_UserProfile.c = "Narnia"

' You must quit and re-launch the office to see the changes take effect.
oConfigData_UserProfile.commitChanges()

' The data will be written to...
' /home/danny/OpenOffice.org1.9.104/user/registry/data/org/openoffice/UserProfile.xcu
' or for some systems...
' C:\Documents and Settings\dbrewer\Application Data\OpenOffice.org1.9.104\user\registry\data\org\openoffice\UserProfile.xcu
End Sub

Function GetConfigAccess( ByVal cNodePath As String,_
                  ByVal bWriteAccess As Boolean,_
                  Optional bEnableSync,_
                  Optional bLazyWrite ) As Object
If IsMissing( bEnableSync ) Then
   bEnableSync = True
EndIf
If IsMissing( bLazyWrite ) Then
   bLazyWrite = False
EndIf

' If bWriteAccess And bEnableSync Then
   oConfigProvider = GetProcessServiceManager().createInstanceWithArguments(_
                  "com.sun.star.configuration.ConfigurationProvider",_
                  Array( MakePropertyValue( "enableasync", bEnableSync ) ) )
' Else
'    oConfigProvider = createUnoService( "com.sun.star.configuration.ConfigurationProvider" )
' EndIf

If bWriteAccess Then
   cServiceName = "com.sun.star.configuration.ConfigurationUpdateAccess"
Else
   cServiceName = "com.sun.star.configuration.ConfigurationAccess"
EndIf

oConfigAccess = oConfigProvider.createInstanceWithArguments( cServiceName,_
   Array( MakePropertyValue( "nodepath", cNodePath ),_
         MakePropertyValue( "lazywrite", bLazyWrite ) ) )

GetConfigAccess = oConfigAccess
End Function

Function MakePropertyValue( Optional cName As String, Optional uValue ) As com.sun.star.beans.PropertyValue
oPropertyValue = createUnoStruct( "com.sun.star.beans.PropertyValue" )
If Not IsMissing( cName ) Then
   oPropertyValue.Name = cName
EndIf
If Not IsMissing( uValue ) Then
   oPropertyValue.Value = uValue
EndIf
MakePropertyValue() = oPropertyValue
End Function

jcd
General User

Joined: 04 Dec 2006
Posts: 30
Location: Morelos, Mexico

Posted: Tue Jul 13, 2010 3:20 pm Post subject:

I want to confirm that under OO ver. 3.2.1, the only properties that are not used by the "User Data" section of the Options dialog are: 'aparment', 'fathersname', and 'UserGroup'.

Display posts from previous:

	OOoForum.org Forum Index -> OpenOffice.org Code Snippets	All times are GMT - 8 Hours
Page 1 of 1

You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot vote in polls in this forum